How to send generic cold-start trap
April 23rd, 2008
Comments off
snmptrap -d -v1 -c community_name host-name SNMPv2-MIB::coldStart “” 6 17 “”
Archive
Archive for the ‘geeky’ Category
HANDY ONE-LINERS FOR SED
April 23rd, 2008
Comments off
————————————————————————-
HANDY ONE-LINERS FOR SED (Unix stream editor) Apr. 26, 2004
compiled by Eric Pement – pemente[at]northpark[dot]edu version 5.4
Latest version of this file is usually at:
http://sed.sourceforge.net/sed1line.txt
http://www.student.northpark.edu/pemente/sed/sed1line.txt
This file is also available in Portuguese at:
http://www.lrv.ufsc.br/wmaker/sed_ptBR.html
FILE SPACING:
# double space a file
sed G
# double space a file which already has blank lines in it. Output file
# should contain no more than one blank line between lines of text.
sed ‘/^$/d;G’
# triple space a file
sed ‘G;G’
# undo double-spacing (assumes even-numbered lines are always blank)
sed ‘n;d’
# insert a blank line above every line which matches “regex”
sed ‘/regex/{x;p;x;}’
# insert a blank line below every line which matches “regex”
sed ‘/regex/G’
# insert a blank line above and below every line which matches “regex”
sed ‘/regex/{x;p;x;G;}’
NUMBERING:
# number each line of a file (simple left alignment). Using a tab (see
# note on ‘\t’ at end of file) instead of space will preserve margins.
sed = filename | sed ‘N;s/\n/\t/’
# number each line of a file (number on left, right-aligned)
sed = filename | sed ‘N; s/^/ /; s/ *\(.\{6,\}\)\n/\1 /’
# number each line of file, but only print numbers if line is not blank
sed ‘/./=’ filename | sed ‘/./N; s/\n/ /’
# count lines (emulates “wc -l”)
sed -n ‘$=’
TEXT CONVERSION AND SUBSTITUTION:
# IN UNIX ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format
sed ‘s/.$//’ # assumes that all lines end with CR/LF
sed ‘s/^M$//’ # in bash/tcsh, press Ctrl-V then Ctrl-M
sed ‘s/\x0D$//’ # gsed 3.02.80, but top script is easier
# IN UNIX ENVIRONMENT: convert Unix newlines (LF) to DOS format
sed “s/$/`echo -e \\\r`/” # command line under ksh
sed ‘s/$’”/`echo \\\r`/” # command line under bash
sed “s/$/`echo \\\r`/” # command line under zsh
sed ‘s/$/\r/’ # gsed 3.02.80
# IN DOS ENVIRONMENT: convert Unix newlines (LF) to DOS format
sed “s/$//” # method 1
sed -n p # method 2
# IN DOS ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format
# Can only be done with UnxUtils sed, version 4.0.7 or higher.
# Cannot be done with other DOS versions of sed. Use “tr” instead.
sed “s/\r//” infile >outfile # UnxUtils sed v4.0.7 or higher
tr -d \r
# delete leading whitespace (spaces, tabs) from front of each line
# aligns all text flush left
sed ‘s/^[ \t]*//’ # see note on ‘\t’ at end of file
# delete trailing whitespace (spaces, tabs) from end of each line
sed ‘s/[ \t]*$//’ # see note on ‘\t’ at end of file
# delete BOTH leading and trailing whitespace from each line
sed ‘s/^[ \t]*//;s/[ \t]*$//’
# insert 5 blank spaces at beginning of each line (make page offset)
sed ‘s/^/ /’
# align all text flush right on a 79-column width
sed -e :a -e ‘s/^.\{1,78\}$/ &/;ta’ # set at 78 plus 1 space
# center all text in the middle of 79-column width. In method 1,
# spaces at the beginning of the line are significant, and trailing
# spaces are appended at the end of the line. In method 2, spaces at
# the beginning of the line are discarded in centering the line, and
# no trailing spaces appear at the end of lines.
sed -e :a -e ‘s/^.\{1,77\}$/ & /;ta’ # method 1
sed -e :a -e ‘s/^.\{1,77\}$/ &/;ta’ -e ‘s/\( *\)\1/\1/’ # method 2
# substitute (find and replace) “foo” with “bar” on each line
sed ‘s/foo/bar/’ # replaces only 1st instance in a line
sed ‘s/foo/bar/4′ # replaces only 4th instance in a line
sed ‘s/foo/bar/g’ # replaces ALL instances in a line
sed ‘s/\(.*\)foo\(.*foo\)/\1bar\2/’ # replace the next-to-last case
sed ‘s/\(.*\)foo/\1bar/’ # replace only the last case
# substitute “foo” with “bar” ONLY for lines which contain “baz”
sed ‘/baz/s/foo/bar/g’
# substitute “foo” with “bar” EXCEPT for lines which contain “baz”
sed ‘/baz/!s/foo/bar/g’
# change “scarlet” or “ruby” or “puce” to “red”
sed ‘s/scarlet/red/g;s/ruby/red/g;s/puce/red/g’ # most seds
gsed ‘s/scarlet\|ruby\|puce/red/g’ # GNU sed only
# reverse order of lines (emulates “tac”)
# bug/feature in HHsed v1.5 causes blank lines to be deleted
sed ’1!G;h;$!d’ # method 1
sed -n ’1!G;h;$p’ # method 2
# reverse each character on the line (emulates “rev”)
sed ‘/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//’
# join pairs of lines side-by-side (like “paste”)
sed ‘$!N;s/\n/ /’
# if a line ends with a backslash, append the next line to it
sed -e :a -e ‘/\\$/N; s/\\\n//; ta’
# if a line begins with an equal sign, append it to the previous line
# and replace the “=” with a single space
sed -e :a -e ‘$!N;s/\n=/ /;ta’ -e ‘P;D’
# add commas to numeric strings, changing “1234567″ to “1,234,567″
gsed ‘:a;s/\B[0-9]\{3\}\>/,&/;ta’ # GNU sed
sed -e :a -e ‘s/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta’ # other seds
# add commas to numbers with decimal points and minus signs (GNU sed)
gsed ‘:a;s/\(^\|[^0-9.]\)\([0-9]\+\)\([0-9]\{3\}\)/\1\2,\3/g;ta’
# add a blank line every 5 lines (after lines 5, 10, 15, 20, etc.)
gsed ’0~5G’ # GNU sed only
sed ‘n;n;n;n;G;’ # other seds
SELECTIVE PRINTING OF CERTAIN LINES:
# print first 10 lines of file (emulates behavior of “head”)
sed 10q
# print first line of file (emulates “head -1″)
sed q
# print the last 10 lines of a file (emulates “tail”)
sed -e :a -e ‘$q;N;11,$D;ba’
# print the last 2 lines of a file (emulates “tail -2″)
sed ‘$!N;$!D’
# print the last line of a file (emulates “tail -1″)
sed ‘$!d’ # method 1
sed -n ‘$p’ # method 2
# print only lines which match regular expression (emulates “grep”)
sed -n ‘/regexp/p’ # method 1
sed ‘/regexp/!d’ # method 2
# print only lines which do NOT match regexp (emulates “grep -v”)
sed -n ‘/regexp/!p’ # method 1, corresponds to above
sed ‘/regexp/d’ # method 2, simpler syntax
# print the line immediately before a regexp, but not the line
# containing the regexp
sed -n ‘/regexp/{g;1!p;};h’
# print the line immediately after a regexp, but not the line
# containing the regexp
sed -n ‘/regexp/{n;p;}’
# print 1 line of context before and after regexp, with line number
# indicating where the regexp occurred (similar to “grep -A1 -B1″)
sed -n -e ‘/regexp/{=;x;1!p;g;$!N;p;D;}’ -e h
# grep for AAA and BBB and CCC (in any order)
sed ‘/AAA/!d; /BBB/!d; /CCC/!d’
# grep for AAA and BBB and CCC (in that order)
sed ‘/AAA.*BBB.*CCC/!d’
# grep for AAA or BBB or CCC (emulates “egrep”)
sed -e ‘/AAA/b’ -e ‘/BBB/b’ -e ‘/CCC/b’ -e d # most seds
gsed ‘/AAA\|BBB\|CCC/!d’ # GNU sed only
# print paragraph if it contains AAA (blank lines separate paragraphs)
# HHsed v1.5 must insert a ‘G;’ after ‘x;’ in the next 3 scripts below
sed -e ‘/./{H;$!d;}’ -e ‘x;/AAA/!d;’
# print paragraph if it contains AAA and BBB and CCC (in any order)
sed -e ‘/./{H;$!d;}’ -e ‘x;/AAA/!d;/BBB/!d;/CCC/!d’
# print paragraph if it contains AAA or BBB or CCC
sed -e ‘/./{H;$!d;}’ -e ‘x;/AAA/b’ -e ‘/BBB/b’ -e ‘/CCC/b’ -e d
gsed ‘/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d’ # GNU sed only
# print only lines of 65 characters or longer
sed -n ‘/^.\{65\}/p’
# print only lines of less than 65 characters
sed -n ‘/^.\{65\}/!p’ # method 1, corresponds to above
sed ‘/^.\{65\}/d’ # method 2, simpler syntax
# print section of file from regular expression to end of file
sed -n ‘/regexp/,$p’
# print section of file based on line numbers (lines 8-12, inclusive)
sed -n ’8,12p’ # method 1
sed ’8,12!d’ # method 2
# print line number 52
sed -n ’52p’ # method 1
sed ’52!d’ # method 2
sed ’52q;d’ # method 3, efficient on large files
# beginning at line 3, print every 7th line
gsed -n ’3~7p’ # GNU sed only
sed -n ’3,${p;n;n;n;n;n;n;}’ # other seds
# print section of file between two regular expressions (inclusive)
sed -n ‘/Iowa/,/Montana/p’ # case sensitive
SELECTIVE DELETION OF CERTAIN LINES:
# print all of file EXCEPT section between 2 regular expressions
sed ‘/Iowa/,/Montana/d’
# delete duplicate, consecutive lines from a file (emulates “uniq”).
# First line in a set of duplicate lines is kept, rest are deleted.
sed ‘$!N; /^\(.*\)\n\1$/!P; D’
# delete duplicate, nonconsecutive lines from a file. Beware not to
# overflow the buffer size of the hold space, or else use GNU sed.
sed -n ‘G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P’
# delete all lines except duplicate lines (emulates “uniq -d”).
sed ‘$!N; s/^\(.*\)\n\1$/\1/; t; D’
# delete the first 10 lines of a file
sed ’1,10d’
# delete the last line of a file
sed ‘$d’
# delete the last 2 lines of a file
sed ‘N;$!P;$!D;$d’
# delete the last 10 lines of a file
sed -e :a -e ‘$d;N;2,10ba’ -e ‘P;D’ # method 1
sed -n -e :a -e ’1,10!{P;N;D;};N;ba’ # method 2
# delete every 8th line
gsed ’0~8d’ # GNU sed only
sed ‘n;n;n;n;n;n;n;d;’ # other seds
# delete ALL blank lines from a file (same as “grep ‘.’ “)
sed ‘/^$/d’ # method 1
sed ‘/./!d’ # method 2
# delete all CONSECUTIVE blank lines from file except the first; also
# deletes all blank lines from top and end of file (emulates “cat -s”)
sed ‘/./,/^$/!d’ # method 1, allows 0 blanks at top, 1 at EOF
sed ‘/^$/N;/\n$/D’ # method 2, allows 1 blank at top, 0 at EOF
# delete all CONSECUTIVE blank lines from file except the first 2:
sed ‘/^$/N;/\n$/N;//D’
# delete all leading blank lines at top of file
sed ‘/./,$!d’
# delete all trailing blank lines at end of file
sed -e :a -e ‘/^\n*$/{$d;N;ba’ -e ‘}’ # works on all seds
sed -e :a -e ‘/^\n*$/N;/\n$/ba’ # ditto, except for gsed 3.02*
# delete the last line of each paragraph
sed -n ‘/^$/{p;h;};/./{x;/./p;}’
SPECIAL APPLICATIONS:
# remove nroff overstrikes (char, backspace) from man pages. The ‘echo’
# command may need an -e switch if you use Unix System V or bash shell.
sed “s/.`echo \\\b`//g” # double quotes required for Unix environment
sed ‘s/.^H//g’ # in bash/tcsh, press Ctrl-V and then Ctrl-H
sed ‘s/.\x08//g’ # hex expression for sed v1.5
# get Usenet/e-mail message header
sed ‘/^$/q’ # deletes everything after first blank line
# get Usenet/e-mail message body
sed ’1,/^$/d’ # deletes everything up to first blank line
# get Subject header, but remove initial “Subject: ” portion
sed ‘/^Subject: */!d; s///;q’
# get return address header
sed ‘/^Reply-To:/q; /^From:/h; /./d;g;q’
# parse out the address proper. Pulls out the e-mail address by itself
# from the 1-line return address header (see preceding script)
sed ‘s/ *(.*)//; s/>.*//; s/.*[:<] *//’
# add a leading angle bracket and space to each line (quote a message)
sed ‘s/^/> /’
# delete leading angle bracket & space from each line (unquote a message)
sed ‘s/^> //’
# remove most HTML tags (accommodates multiple-line tags)
sed -e :a -e ‘s/<[^>]*>//g;/
# extract multi-part uuencoded binaries, removing extraneous header
# info, so that only the uuencoded portion remains. Files passed to
# sed must be passed in the proper order. Version 1 can be entered
# from the command line; version 2 can be made into an executable
# Unix shell script. (Modified from a script by Rahul Dhesi.)
sed '/^end/,/^begin/d' file1 file2 ... fileX | uudecode # vers. 1
sed '/^end/,/^begin/d' "$@" | uudecode # vers. 2
# zip up each .TXT file individually, deleting the source file and
# setting the name of each .ZIP file to the basename of the .TXT file
# (under DOS: the "dir /b" switch returns bare filenames in all caps).
echo @echo off >zipup.bat
dir /b *.txt | sed “s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/” >>zipup.bat
TYPICAL USE: Sed takes one or more editing commands and applies all of
them, in sequence, to each line of input. After all the commands have
been applied to the first input line, that line is output and a second
input line is taken for processing, and the cycle repeats. The
preceding examples assume that input comes from the standard input
device (i.e, the console, normally this will be piped input). One or
more filenames can be appended to the command line if the input does
not come from stdin. Output is sent to stdout (the screen). Thus:
cat filename | sed ’10q’ # uses piped input
sed ’10q’ filename # same effect, avoids a useless “cat”
sed ’10q’ filename > newfile # redirects output to disk
For additional syntax instructions, including the way to apply editing
commands from a disk file instead of the command line, consult “sed &
awk, 2nd Edition,” by Dale Dougherty and Arnold Robbins (O’Reilly,
1997; http://www.ora.com), “UNIX Text Processing,” by Dale Dougherty
and Tim O’Reilly (Hayden Books, 1987) or the tutorials by Mike Arst
distributed in U-SEDIT2.ZIP (many sites). To fully exploit the power
of sed, one must understand “regular expressions.” For this, see
“Mastering Regular Expressions” by Jeffrey Friedl (O’Reilly, 1997).
The manual (“man”) pages on Unix systems may be helpful (try “man
sed”, “man regexp”, or the subsection on regular expressions in “man
ed”), but man pages are notoriously difficult. They are not written to
teach sed use or regexps to first-time users, but as a reference text
for those already acquainted with these tools.
QUOTING SYNTAX: The preceding examples use single quotes (‘…’)
instead of double quotes (“…”) to enclose editing commands, since
sed is typically used on a Unix platform. Single quotes prevent the
Unix shell from intrepreting the dollar sign ($) and backquotes
(`…`), which are expanded by the shell if they are enclosed in
double quotes. Users of the “csh” shell and derivatives will also need
to quote the exclamation mark (!) with the backslash (i.e., \!) to
properly run the examples listed above, even within single quotes.
Versions of sed written for DOS invariably require double quotes
(“…”) instead of single quotes to enclose editing commands.
USE OF ‘\t’ IN SED SCRIPTS: For clarity in documentation, we have used
the expression ‘\t’ to indicate a tab character (0×09) in the scripts.
However, most versions of sed do not recognize the ‘\t’ abbreviation,
so when typing these scripts from the command line, you should press
the TAB key instead. ‘\t’ is supported as a regular expression
metacharacter in awk, perl, and HHsed, sedmod, and GNU sed v3.02.80.
VERSIONS OF SED: Versions of sed do differ, and some slight syntax
variation is to be expected. In particular, most do not support the
use of labels (:name) or branch instructions (b,t) within editing
commands, except at the end of those commands. We have used the syntax
which will be portable to most users of sed, even though the popular
GNU versions of sed allow a more succinct syntax. When the reader sees
a fairly long command such as this:
sed -e ‘/AAA/b’ -e ‘/BBB/b’ -e ‘/CCC/b’ -e d
it is heartening to know that GNU sed will let you reduce it to:
sed ‘/AAA/b;/BBB/b;/CCC/b;d’ # or even
sed ‘/AAA\|BBB\|CCC/b;d’
In addition, remember that while many versions of sed accept a command
like “/one/ s/RE1/RE2/”, some do NOT allow “/one/! s/RE1/RE2/”, which
contains space before the ‘s’. Omit the space when typing the command.
OPTIMIZING FOR SPEED: If execution speed needs to be increased (due to
large input files or slow processors or hard disks), substitution will
be executed more quickly if the “find” expression is specified before
giving the “s/…/…/” instruction. Thus:
sed ‘s/foo/bar/g’ filename # standard replace command
sed ‘/foo/ s/foo/bar/g’ filename # executes more quickly
sed ‘/foo/ s//bar/g’ filename # shorthand sed syntax
On line selection or deletion in which you only need to output lines
from the first part of the file, a “quit” command (q) in the script
will drastically reduce processing time for large files. Thus:
sed -n ’45,50p’ filename # print line nos. 45-50 of a file
sed -n ’51q;45,50p’ filename # same, but executes much faster
If you have any additional scripts to contribute or if you find errors
in this document, please send e-mail to the compiler. Indicate the
version of sed you used, the operating system it was compiled for, and
the nature of the problem. Various scripts in this file were written
or contributed by:
Al Aab
Edgar Allen
Yiorgos Adamopoulos
Dale Dougherty
Carlos Duarte
Eric Pement
Ken Pizzini
S.G. Ravenhall
Greg Ubben
————————————————————————-
Rands In Repose: The Nerd Handbook
February 10th, 2008
No comments
Rands In Repose: The Nerd Handbook: “The Nerd Handbook
A nerd needs a project because a nerd builds stuff. All the time. Those lulls in the conversation over dinner? That’s the nerd working on his project in his head.
It’s unlikely that this project is a nerd’s day job because his opinion regarding his job is, ‘Been there, done that’. We’ll explore the consequences of this seemingly short attention span in a bit, but for now this project is the other big thing your nerd is building and I’ve no idea what is, but you should.
At some point, you, the nerd’s companion, were the project. You were showered with the fire hose of attention because you were the bright and shiny new development in your nerd’s life. There is also a chance that you’re lucky and you are currently your nerd’s project. Congrats. Don’t get too comfortable because he’ll move on, and, when that happens, you’ll be wondering what happened to all the attention. This handbook might help.
Regarding gender: for this piece, my prototypical nerd is a he as a convenience. There are plenty of she nerds out there for which these observations equally apply.
Understand your nerd’s relation to the computer. It’s clichéd, but a nerd is defined by his computer, and you need to understand why.
First, a majority of the folks on the planet either have no idea how a computer works or they look at it and think ‘it’s magic’. Nerds know how a computer works. They intimately know how a computer works. When you ask a nerd, ‘When I click this, it takes awhile for the thing to show up. Do you know what’s wrong?’ they know what’s wrong. A nerd has a mental model of the hardware and the software in his head. While the rest of the world sees magic, your nerd knows how the magic works, he knows the magic is a long series of ones and zeros moving across your screen with impressive speed, and he knows how to make those bits move faster.
The nerd has based his career, maybe his life, on the computer, and as we’ll see, this intimate relationship has altered his view of the world. He sees the world as a system which, given enough time and effort, is completely knowable. This is a fragile illusion that your nerd has adopted, but it’s a pleasant one that gets your nerd through the day. When the illusion is broken, you are going to discover that…
Your nerd has control issues. Your nerd lives in a monospaced typeface world. Whereas everyone else is traipsing around picking dazzling fonts to describe their world, your nerd has carefully selected a monospace typeface, which he avidly uses to manipulate the world deftly via a command line interface while the rest fumble around with a mouse.
The reason for this typeface selection is, of course, practicality. Monospace typefaces have a knowable width. Ten letters on one line are same width as ten other letters, which puts the world into a pleasant grid construction where X and Y mean something.
These control issues mean your nerd is sensitive to drastic changes in his environment. Think travel. Think job changes. These types of system-redefining events force your nerd to recognize that the world is not always or entirely a knowable place, and until he reconstructs this illusion, he’s going to be frustrated and he’s going to act erratically. I develop an incredibly short fuse during system-redefining events and I’m much more likely to lose it over something trivial and stupid. This is one of the reasons that…
Your nerd has built himself a cave. I’ve written about The Cave elsewhere, but here are the basics. The Cave is designed to allow your nerd to do his favorite thing, which is working on the project. If you want to understand your nerd, stare long and hard at his Cave. How does he have it arranged? When does he tend to go there? How long does he stay?
Each object in the Cave has a particular place and purpose. Even the clutter is well designed. Don’t believe me? Grab that seemingly discarded Mac Mini which has been sitting on the floor for two months and hide it. You’ll have 10 minutes before he’ll come stomping out of the Cave — ‘Where’s the Mac?’
The Cave is also frustrating you because your impression is that it’s your nerd’s way of checking out, and you are, unfortunately, completely correct. A correctly designed Cave removes your nerd from the physical world and plants him firmly in a virtual one complete with all the toys he needs. Because…
Your nerd loves toys and puzzles. The joy your nerd finds in his project is one of problem solving and discovery. As each part of the project is completed, your nerd receives an adrenaline rush that we’re going to call The High. Every profession has this — the moment when you’ve moved significantly closer to done. In many jobs, it’s easy to discern when progress is being made: ‘Look, now we have a door’. But in nerds’ bit-based work, progress is measured mentally and invisibly in code, algorithms, efficiency, and small mental victories that don’t exist in a world of atoms.
There are other ways your nerd can create The High and he does it all the time. It’s another juicy cliché to say that nerds love video games, but that’s not what they love. A video game is just one more system where your nerd’s job is to figure out the rules that define it, which will enable him to beat it. Yeah, we love to stare at games with a bazillion polygons, but we get the same high out of playing Bejeweled, getting our Night Elf to Level 70, or endlessly tinkering with a Rubik’s Cube. This fits nicely with the fact that…
Nerds are fucking funny. Your nerd spent a lot of his younger life being an outcast because of his strange affinity with the computer. This created a basic bitterness in his psyche that is the foundation for his humor. Now, combine this basic distrust of everything with your nerd’s other natural talents and you’ll realize that he sees humor is another game.
Humor is an intellectual puzzle, ‘How can this particular set of esoteric trivia be constructed to maximize hilarity as quickly as possible?’ Your nerd listens hard to recognize humor potential and when he hears it, he furiously scours his mind to find relevant content from his experience so he can get the funny out as quickly as possible.
This quick wit is only augmented by the fact that…
Your nerd has an amazing appetite for information. Many years ago, I dubbed this behavior NADD, and you should read the article to learn more and to understand what mental muscles your nerd has developed.
How does a nerd watch TV? Probably one of two ways. First, there’s watching TV with you where the two of you sit and watch one show. Then there’s how he watches by himself when he watches three shows at once. It looks insane. You walk into the room and you’re watching your nerd jump between channels every five minutes.
‘How can you keep track of anything?’
He keeps track of everything. See, he’s already seen all three of these movies… multiple times. He knows the compelling parts of the arcs and is mentally editing his own versions while watching all three. The basic mental move here is the context switch, and your nerd is the king of the context switch.
The ability to instantly context switch also comes from a life on the computer. Your nerd’s mental information model for the world is one contained within well-bounded tidy windows where the most important tool is one that allows your nerd to move swiftly from one window to the next. It’s irrelevant that there may be no relationship between these windows. Your nerd is used to making huge contextual leaps where he’s talking to a friend in one window, worrying about his 401k in another, and reading about World War II in yet another.
You might suspect that given a world where context is constantly shifting, your nerd can’t focus, and you’d be partially correct. All that multi-tasking isn’t efficient. Your nerd knows very little about a lot. For many topics, his knowledge is an inch deep and four miles wide. He’s comfortable with this fact because he knows that deep knowledge about any topic is a clever keystroke away. See…
Your nerd has built an annoyingly efficient relevancy engine in his head. It’s the end of the day and you and your nerd are hanging out on the couch. The TV is off. There isn’t a computer anywhere nearby and you’re giving your nerd the daily debrief. ‘Spent an hour at the post office trying to ship that package to your mom, and then I went down to that bistro — you know — the one next the flower shop, and it’s closed. Can you believe that?’
And your nerd says, ‘Cool’.
Cool? What’s cool? The business closing? The package? How is any of it cool? None of it’s cool. Actually, all of it might be cool, but your nerd doesn’t believe any of what you’re saying is relevant. This is what he heard, ‘Spent an hour at the post office blah blah blah…’
You can be rightfully pissed off by this behavior — it’s simply rude — but seriously, I’m trying to help here. Your nerd’s insatiable quest for information and The High has tweaked his brain in an interesting way. For any given piece of incoming information, your nerd is making a lightning fast assessment: relevant or not relevant? Relevance means that the incoming information fits into the system of things your nerd currently cares about. Expect active involvement from your nerd when you trip the relevance flag. If you trip the irrelevance flag, look for verbal punctuation announcing his judgment of irrelevance. It’s the word your nerd says when he’s not listening and it’s always the same. My word is ‘Cool’, and when you hear ‘Cool’, I’m not listening.
Information that your nerd is exposed to when the irrelevance flag is waving is forgotten almost immediately. I mean it. Next time you hear ‘Cool’, I want you to ask, ‘What’d I just say?’ That awkward grin on your nerd’s face is the first step in getting him to acknowledge that he’s the problem in this particular conversation. This behavior is one of the reasons that…
Your nerd might come off as not liking people. Small talk. Those first awkward five minutes when two people are forced to interact. Small talk is the bane of the nerd’s existence because small talk is a combination of aspects of the world that your nerd hates. When your nerd is staring at a stranger, all he’s thinking is, ‘I have no system for understanding this messy person in front of me’. This is where the shy comes from. This is why nerds hate presenting to crowds.
The skills to interact with other people are there. They just lack a well-defined system.
Advanced Nerd Tweakage
If you’re still reading, then I’m thinking that your nerd is worth keeping. Even though he’s apt to vanish for hours, has a strange sense of humor, doesn’t like you touching his stuff, and often doesn’t listen when you’re talking directly at him, he’s a keeper. Go figure.
My advice:
Map the things he’s bad at to the things he loves. You love to travel, but your nerd would prefer to hide in his cave for hours on end chasing The High. You need to convince him of two things. First, you need to convince him that you’re going to do your best to recreate his cave in his new surrounding. You’re going to create a quiet, dark place here he can orient himself and figure out which way the water flushes down the toilet. Traveling internationally? Carve out three days somewhere quiet at the beginning of the trip. Traveling across the US? How about letting him chill on the bed for a half-day before you drag him out to see the Golden Gate Bridge?
Second, and more importantly, you need to remind him about his insatiable appetite for information. You need to appeal to his deep love of discovering new content and help him understand that there may be no greater content fire hose than waking up in a hotel overlooking the Grand Canal in Venice where you don’t speak a word of Italian.
Make it a project. You might’ve noticed your nerd’s strange relation to food. Does he eat fast? Like really fast? You should know what’s going on here. Food is thrown into the irrelevant bucket because it’s getting in the way of the content. Exercise, too. Thing is, you want your nerd to eat healthily so that he’s here in another thirty years, so how do you change this behavior? You make diet and exercise the project.
For me, exercise became the project ten years ago after a horrible break-up. When the project was no longer the Ex, I dove into exercise every single day of the week. There were charts tracking my workouts, there were graphs tracking my weight, and there was the exercise. Every single day for two years until the day I passed out in a McDonald’s post-workout after not eating for a day. Ok, so time for a new project. Yeah, nerds also have moderation issues. That’s another essay.
Significant nerd behavioral change is only going to happen if your nerd engages in the project heart and soul, otherwise it’s just another thought for the irrelevant bucket.
People are the most interesting content out there. If you’ve got a seriously shy nerd on your hands, try this: ask him how many folks are in his buddy list? How many friends does he have in Facebook? How many folks are following him on Twitter? LiveJournal? My guess is that, collectively, your nerd interacts with ten times more people than you think he does. He can do this because the interaction is via a system he understands — the computer.
Your nerd knows that people are interesting. Just because he can’t look your best friend straight in the eye doesn’t mean he doesn’t want to know what makes her tick, but you need to be the social buffer — the translation layer. You need to find one common thread of interest between your nerd and your friend and then he’ll engage because he will have found relevance.
The Next High
As you discovered when you were the project, your nerd’s focus can be deliciously overwhelming, but it will stop. Once a nerd believe he fully knows how a system works, the challenge to understand ceases to exist and he moves on in search of The Next High.
While I don’t know who you are or why in the world you chose a nerd for your companion, I do know that you are not a knowable system. I know that you are messy, just like your nerd. Being your own quirky self will be more than enough to present new and interesting challenges to your nerd.
Besides, it’s just as much a nerd’s job to figure you out and maybe someone somewhere is writing an article about your particular quirks. Good news, he’s probably reading it right now.”
(Via Rands in Repose.)
Categories: geeky